Issue
Continuum and Mantrap or Interlock Interval
Product Line
Andover Continuum
Environment
Continuum site with Access Control
Cause
Site needing to setup a Mantrap or Interlock Interval for higher security of an area
Resolution
What is a mantrap? A mantrap is a security device that monitors and controls two or more interlocking doors to a small room that separates a non-secured area from a secured area. These interlocking doors allow only one door to be open at any time.
What are interlocking doors? “Interlocking doors” is a security term used to describe how two or more doors are interfaced with each other and locked. Doors that are interlocked cannot be open at the same time. Either door can be unlocked and opened as long as the other door is locked and closed, and no other alarm condition exists.
What types of locations require a mantrap? Mantraps are used at high value or critical security areas where only authorized persons are allowed to enter. Typical areas include sensitive data processing areas, cash handling areas, critical research labs, security control rooms, and automated airline passenger entry portals.
Why would my company consider a mantrap? Typically, security personnel are posted in high security locations to control access into the area. An automatic mantrap used in this same location would control the access to the area, allowing security personnel resources to be available for other tasks.
What is the difference between a mantrap and an interlocking door control system? When speaking of controlling two doors within a vestibule, “mantrap” and “interlocking door controller” can be used interchangeably. Once the number of doors controlled by a single controller exceeds two then the term interlocking door controller should be used.
Continuum Mantraps are accomplished by a PE Program. Interlock Interval is available at the bottom of this article. Here is a simple mantrap program written as a sample.
ManTrap_A and ManTrap_B are the doors that make up the man trap
-------------
'This program implements a Man Trap that allows one person at a time in the man trap.
'Once a person is in the man trap no access is allowed until the occupant leaves the man trap via the REX.
' The occupant is allowed to exit at either door but once they have activated the REX at one door
'they are required to leave via that door.
'If occupant stays in the trap longer than TrapMaxOccTime and alarm can be sent via ManTrapStuck
'TrapMaxOccTime and ManTrapStuck are InfinityNumeric objects in the controller.
'Program is Looping and AutoStart
TRAP_READY:
ManTrap_A DisRdrKpAccess = False
ManTrap_B DisRdrKpAccess = False
ManTrap_A OpenOnExitReqst = True
ManTrap_B OpenOnExitReqst = True
If ManTrap_A ValidAccess or ManTrap_B ValidAccess then Goto TRAP_OCCUPIED
TRAP_OCCUPIED:
ManTrap_A DisRdrKpAccess = True
ManTrap_B DisRdrKpAccess = True
If ManTrap_B ExitRequest then
ManTrap_A OpenOnExitReqst = False
Goto WAIT_EXIT_B
Endif
If ManTrap_A ExitRequest then
ManTrap_B OpenOnExitReqst = False
Goto WAIT_EXIT_A
Endif
WAIT_EXIT_A:
If ManTrap_A DoorSwitch = Opened then Goto TRAP_READY
If TS > TrapMaxOccTime then ManTrapStuck = On
WAIT_EXIT_B:
If ManTrap_B DoorSwitch = Opened then Goto TRAP_READY
If TS > TrapMaxOccTime then ManTrapStuck = On
'Keep program from disabling due to run time errors
E:
if ts > 30 then goto TRAP_READY
For Interlock Interval please use this PDF. Interlock is hardware controlled, not through a PE.
